PLseq | SuperCollider 3.13.0 Help

Description

Takes Symbol args for later reference by the Streams, which will read from variables in the Environments of their instantiation. See PLx_suite.

Class Methods

.new

Creates a new PLseq object.

Arguments:

list	Symbol or Pseq list arg. If a Symbol is passed, list can be assigned to an envir variable later on. This lists's elements can be dynamically replaced by Patterns or Streams.
repeats	Symbol or Pseq repeats arg. If a Symbol is passed, repeats can be assigned to an envir variable later on. Defaults to inf.
offset	Symbol or Pseq offset arg. Defaults to 0. If a Symbol is passed, offset can be assigned to an envir variable later on.
cutItems	Symbol or Boolean or Integer (0 or 1) or a Function returning Boolean or Integer. If a Symbol is passed, cutItems can be assigned to an envir variable later on. Determines if list items, which are Patterns or Streams themselves, will be finished if a replacement occurs during their embedding, or if they will be replaced immediately. The latter is the default behaviour (default value true). For protecting whole lists from immediate replacements see PLn.
envir	Dictionary or one of the Symbols \top, \t (topEnvironment), \current, \c (currentEnvironment). Dictionary to be taken for variable reference. Defaults to \current.

Examples

(
s = Server.local;
Server.default = s;
s.boot;
)

// definition for future reference in arbitrary Environments

(
p = Pbind(
    \midinote, PLseq(\a),
    \dur, 0.1
);
)

// assign a value to variable ~a in current Environment,
// play there.
// PLseq defaults to repeats = inf, Pseq defaults to repeats = 1

(
~a = (67..70) ++ Pseq((99..70));

x = p.play;
)

// try replacing Pseq stream while chromatic line down,
// works immediately with default value cutItems = true

~a[4] = 73;

// replace whole list

~a = (60..65);

x.stop;

//////////////////////

// placeholder may also get lists of event patterns

(
p = PLseq(\a);

~a = [
    Pbind(
        \midinote, Pwhite(60, 65, 3),
        \dur, 0.2
    ),
    Pbind(
        \midinote, Pwhite(80, 85, 3),
        \dur, 0.2
    )
];

x = p.play;
)

// replace array element

(
~a[0] = Pbind(
    \midinote, Pwhite(70, 75, 3) + [0, 5],
    \dur, 0.15
);
)

// replace whole array

(
~a = [ Pbind(
        \midinote, Pwhite(60, 65, 3),
        \dur, 0.05
    ),
    Pbind(
        \midinote, Pwhite(70, 90, 2),
        \dur, 0.25
        )
];
)

x.stop;

helpfile source: HelpSource/Classes/PLseq.schelp
link::miSCellaneous_lib/Classes/PLseq::

PLseqExtension

Description

Class Methods

.new

Arguments:

Examples

PLseq
Extension