MPadView | SuperCollider 3.13.0 Help

Description

MPadView is used in MKtlGUIs to automatically generate representations of pads and piano keys as commonly used in MIDI devices. You may never need to use MPadView explicitly.

It flexibly supports a variety of behaviors these noteOn, noteOff and touch elements may have, discussed here for clarity, and to possibly add more arcane combinations when encountered.

These types of MIDI elements include:

tag:	description:	noteOn:	noteOff:	touch:	comment

\noteOnTrig	trigger pad	127	-	-
\noteOnVel	trig pad w/ vel.	1-127	-	-

\noteOnOff	piano key w/ on vel.	1-127	0	-	default
\noteOnOffBut	button on/off	127	0	-
\noteOnOffVel	pad/key w/ off vel.	1-127	1-127	-	rare

\noteOnOffTouch	pad/key w/ polytouch	1-127	0	0-127	semi-rare
\noteOnOffVelTouch	pad/key w/ off vel and touch	1-127	1-127	1-127	very rare

Code Examples for demonstration:

// make a little keyboard to try the different modes:
(
~win = Window("PianoLayout", Rect(0, 200, 400, 200)).front;
// switch between modes:
~pop = EZPopUpMenu(~win, Rect(4, 4, 192, 24), "mode",
    MPadView.modeKeys, { |pop|
        pop.item.postln;
        ~keys.do(_.mode_(pop.item));
}, labelWidth: 40);

// sort black before white keys so we draw them on top
~layouts = Piano.layout(48, 72).sort { |a, b| a.color > b.color };

// draw MPadViews as keys
~keys = ~layouts.collect { |ev|
    var color = Color.perform(ev.color);
    var height = ev.h * 60;
    var rect = Rect(ev.x + (1-ev.w/2) * 24 + 4, 30 + 4, 24 * ev.w, height);
    var pad = MPadView(~win, rect);
    pad.baseColor_(color).label_(ev.note);
    pad.vShiftLabel_( ev.h * 15);
    pad.action = { |pd| "pad %    on: % \n".postf(ev.note, pd.value.round(0.001)) };
    pad.upAction = { |pd| "pad %   off: % \n".postf(ev.note, pd.upValue.round(0.001)) };
    pad.moveAction = { |pd| "pad % touch: % \n".postf(ev.note, pd.moveValue.round(0.001)) };
};
)

// make a single MPadView and show its modes / behavior in more detail:

m = MPadView().front;
// set its basic actions for mouseDown, mouseUp and mouseMove
m.action = { |mp| "noteOn vel: %\n".postf(mp.value.round(0.001)) };
m.upAction = { |mp| "noteOff vel: %\n".postf(mp.upValue.round(0.001)) };
m.moveAction = { |mp| "touch value: %\n".postf(mp.moveValue.round(0.001)) };

// -> try its default behavior:
m.mode;
m.label_(m.mode);
// y-pos on pad determines noteOn velocity, noteOff is 0, touch is off
// post its internal settings
[m.useValue, m.useUpValue, m.useMoveValue, m.autoUpTime ];

// noteOn/off button only - turn off useValue
m.mode_(\noteOnOffBut).label_(m.mode);
[m.useValue, m.useUpValue, m.useMoveValue, m.autoUpTime ];

// use noteOn, e.g. for simple trigger pads:
m.mode_(\noteOnTrig).label_(m.mode);
// hold value for m.autoUpTime, then velocity falls by itself
[m.useValue, m.useUpValue, m.useMoveValue, m.autoUpTime ];

// use only noteOn with velocity, e.g. for drum pads:
m.mode_(\noteOnVel).label_(m.mode);
[m.useValue, m.useUpValue, m.useMoveValue, m.autoUpTime ];

// useMouseMove to enable polytouch sensing on key
m.mode_('noteOnOffTouch').label_(m.mode);
[m.useValue, m.useUpValue, m.useMoveValue, m.autoUpTime ];

// noteOff : enable velocity
m.mode_('noteOnOffVel').label_(m.mode);
[m.useValue, m.useUpValue, m.useMoveValue, m.autoUpTime ];

// noteOff : enable velocity
m.mode_('noteOnOffVelTouch').label_(m.mode);
[m.useValue, m.useUpValue, m.useMoveValue, m.autoUpTime ];

// won't switch when nonexistent mode
m.mode_(\noSuchMode);

m.baseColor = Color.grey(0.25);

Class Methods

.new

Arguments:

parent
bounds	make a new instance of an MPadView

.modes

a dictionary of modes, see top example

.modeKeys

names of the available behavior modes

Instance Methods

.mode

get and set behavior mode of the mpadview. modeName is one of MPadView.modeKeys.

.baseColor

get and set mpadview's background color

.hiliteColor

get and set color for activities on view

.value

.label

get and set view label to show

.vShiftLabel

shift label by vertical offset

.font

get and set font to use for label

helpfile source: Modality/HelpSource/Classes/MPadView.schelp
link::Modality-toolkit/Classes/MPadView::

MPadView
Extension

Description

Code Examples for demonstration:

Class Methods

.new

Arguments:

.modes

.modeKeys

Instance Methods

.mode

.baseColor

.hiliteColor

.value

.valueAction

.upValue

.upValueAction

.moveValue

.moveValueAction

.useValue

.useUpValue

.useMoveValue

.action

.upAction

.moveAction

.doAction

.doUpAction

.doMoveAction

.pressed

.autoUpTime

.label

.vShiftLabel

.font

MPadViewExtension

Description

Code Examples for demonstration:

Class Methods

.new

Arguments:

.modes

.modeKeys

Instance Methods

.mode

.baseColor

.hiliteColor

.value

.valueAction

.upValue

.upValueAction

.moveValue

.moveValueAction

.useValue

.useUpValue

.useMoveValue

.action

.upAction

.moveAction

.doAction

.doUpAction

.doMoveAction

.pressed

.autoUpTime

.label

.vShiftLabel

.font

MPadView
Extension