HilbertWIm | SuperCollider 3.13.0 Help

Description

Offers the Hilbert Transform of an input signal via Weaver's Third Method.¹

The Hilbert Transform, returning the second of two signals in phase-quadrature. Considered as a complex analytic signal, ² the first may be regarded as the real component and the second as the imaginary.

[1] this is a composite pseudo UGen. HilbertWIm is built with Delay1, Delay2, Impulse, LocalBuf, FFT, IFFT, and PV_BrickWall.

Class Methods

.ar

Arguments:

in	The input signal to transform.
size	The size of the FFT used for Weaver Half-Band filtering.
mul	Output will be multiplied by this value.
add	This value will be added to the output.

Returns:

The imaginary part of the Hilbert Transform.

Frequency response

Please review the discussion found here.

Examples

FFT analysis functions

NOTE: FFT returns linear frequency

*/
(
~calcMag = { arg kernel;

var fftResponse, fftMag;

// FFT analysis here!
    fftResponse = fft(
        kernel.as(Signal),
        Signal.newClear(kernel.size),
        Signal.fftCosTable(kernel.size)
    );

// find (& trim magnitude)
    fftMag = fftResponse.magnitude;
    fftMag = fftMag.copyFromStart((kernel.size/2).asInteger);

fftMag;
};
)

/*
        TEST Weaver : HilbertWIm

Impulse Response
*/
(
var size, dur, freq;
var overSample, start;
var plotDbMin, plotDbMax;

// kernel size
size = 2048;

overSample = 2;

// plot params
plotDbMin = -60.0;
plotDbMax = 6.0;

start = size  - ((size/2).asInt) - s.options.blockSize;  // offset - for kernel normalized to sample delay

dur = size / s.sampleRate;  // in seconds
freq = dur.reciprocal;

fork {
    { // imaginary
        HilbertWIm.ar(
            Impulse.ar(freq), // imulse test, one pulse over fftbuffer size
        size: size);
    }.loadToFloatArray(overSample * dur, s, {
        |arr|
        defer {
            arr = arr.copyRange(start, start+size-1);
            arr.plot("Imaginary; HilbertWIm; Impulse input", minval: -1, maxval: 1);
        }
        }
    );

0.5.wait;

{ // plot magnitude - imaginary
        HilbertWIm.ar( // imaginary
            Impulse.ar(freq), // imulse test, one pulse over fftbuffer size
        size: size);
    }.loadToFloatArray(overSample * dur, s, {
        |arr|
        defer {
            arr = arr.copyRange(start, start+size-1);
            ~calcMag.value(arr).ampdb.plot(
                name: "Imaginary Magnitude Response",
                minval: plotDbMin,
                maxval: plotDbMax
            );
        }
        }
    );

}
)

/*
        TEST Weaver : HilbertWIm

single cosine cycle: period = size
*/

(
var size, dur, freq;
var overSample, start;

size = 2048;
overSample = 3;
// plot: jump to the 2nd cycle, to account for "warm up" of Im kernel
start = 2 * size - s.options.blockSize;  // offset - to sync cycle

dur = size / s.sampleRate;  // in seconds
freq = dur.reciprocal;

{ // imaginary
    HilbertWIm.ar(
        SinOsc.ar(freq, pi/2), // cosine test, one cycle over fftbuffer size
        size: size);
}.loadToFloatArray(overSample * dur, s, {
    |arr|
    defer {
        arr = arr.copyRange(start, start+size-1);
        arr.plot("Imaginary; HilbertWIm; Cosine input", minval: -1, maxval: 1);
    }
}
);
)

[1] - Weaver, Donald. “A Third Method of Generation and Detection of Single-Sideband Signals.” Proceedings of the IRE, vol. 44, no. 12, 1956, pp. 1703–1705.

[2] - Smith, J.O. “Analytic Signals and Hilbert Transform Filters”, in Mathematics of the Discrete Fourier Transform (DFT) with Audio Applications, Second Edition, https://ccrma.stanford.edu/~jos/st/Analytic_Signals_Hilbert_Transform.html, online book, 2007 edition, accessed 2017-08-08.

helpfile source: HelpSource/Classes/HilbertWIm.schelp
link::Hilbert/Classes/HilbertWIm::

HilbertWImExtension