Fracture | SuperCollider 3.13.0 Help

Description

Fracture is a tool for live indexing of pitch-indexed chips from a buffer. During buffer recording, "chips" are recorded according to the input's satisfaction of amplitude and pitch consistency thresholds. Chips are events of the type \chip that play on their parent fracture's default synth, or another synth spawned by the object FractureSynth. Fracture works best with monophonic pitched audio sources, but can also be used for without the pitch feature for simple transient detection.

Class Methods

.new

Create a new Fracture.

Arguments:

server	The server on which to allocate the buffer
in	Input bus or integer specifying hardware input channel
bufferSize	The size in seconds of the internal buffer
loopRecord	true = continue to record the buffer once it is full, overwriting its original contents and replacing associated chips. false = stop recording the buffer once it is full and lock the fracture
ampThresh	Minimum amplitude level for chips to be recorded.
pitchThresh	Minimum pitch detectability value (0..1).
minDur	Minimum chip duration in seconds.
maxDur	Maximum chip duration in seconds.

.load

Load a fracture from disk.

Arguments:

server	The server on which to allocate the buffer
path	Directory containing a buffer (AIFF) and chips archive (.TXT) to be loaded. If none specified, select path from dialog.

Instance Methods

.open

Start recording the fracture's buffer and indexing chips from the beginning or the point at which the fracture was last closed.

.close

Pause recording of the buffer. Chip library remains intact.

.save

Save the buffer and chip library to disk.

Arguments:

path	Directory in which the fracture's buffer (AIFF) and chips archive (.TXT) will be saved. If none specified, select path from dialog.

.clear

Stop recording processes and clear the buffer and chip library

.lock

Lock the fracture to prevent it from being opened. A Fracture cannot be unlocked once it has been locked.

.chips

Returns:

The array of chips recorded by this buffer.

.notes

Returns:

An array of available MIDI pitches encompassed by the chips in the fracture's library.

.noteChips

Returns:

An array of chips that match the given MIDI pitch or array of pitches.

.playNote

Play a random chip matching the note or array of notes provided.

.buffer

Returns:

The fracture's buffer.

.filePath

Returns:

The path of this fracture's save directory (if the fracture has been saved or loaded).

.defaultSynth

Get or set the fracture's default SynthDef (the default instrument for all chips created by this fracture). See FractureSynth.

.writeInterval

Get or set the interval at which the fracture analyzes audio and writes chips.

.clearInterval

Get or set the interval at which the fracture refreshes its chip library.

.ampThresh

Get or set the amplitude threshold of this fracture.

.pitchThresh

Get or set the pitch consistency threshold of this fracture (0..1).

.minDur

Get or set the minimum chip duration for this fracture in seconds.

.minDur

Get or set the maximum chip duration for this fracture in seconds.

Examples

//Create a new fracture:
f = Fracture.new(s, 0)

//Start recording and indexing "chips":
f.open

// Hum some notes...

//Now call "chips" to see the events we've created:
f.chips

//Each chip is stored as a modified note event. Play a random chip from the buffer:
f.chips.choose.play

//You can also choose an available note from the chips library...
n = f.notes.choose

//...and play back chips of that pitch:
f.noteChips(n).choose.play

//A Fracture comes with a default synth for chip playback:
f.defaultSynth

//You can create a new SynthDefs with FractureSynth for variable pitch playback:
i = FractureSynth.new(f, 2, pan: \pos, rate: 2)
j = FractureSynth.new(f, 2, pan: \pitch, env: [0.8, 0.1, \sine], rate: 0.5)
f.chips.choose.put(\instrument, i).play // play with position-based panning at a rate of 2
f.chips.choose.put(\instrument, j).play //play with pitch-based panning and narrower envelope at a rate of 0.5

//Use patterns to integrate chips into pitch-based playback streams:

//nice blended single tone
(
p = Pbindf(Pcollect({|n| f.noteChips(n).choose ?? Rest(0.2)}, Pseq([f.notes.choose], inf)),
    \dur, Pfunc({|e| (e[\end] - e[\start])/f.buffer.sampleRate}),
    \amp, Penv([0, 0.5, 0], [0.2, 4], 'sine'),
    \stretch, 0.5,
).play
)
p.stop

//crazy rate envelope
(
p = Pbindf(Pseq(f.chips, inf),
    \dur, Pfunc({|e| (e[\end] - e[\start])/f.buffer.sampleRate}),
    \pan, Pn(Pseq([-1, 1, -0.6, 0.6, -0.2, 0.2, 0]), inf),
    \rate, Pn(Penv([1, 2, 0.3, 1], [0.5, 0.5, 0.5]), inf),
    \amp, Penv([0, 0.5, 0], [3, 4], 'sine'),
).play
)
p.stop

//percussive pattern going up the scale
(
i = FractureSynth.new(f, 2, \pitch, env: [0.05, 0.8, 'sine']);
p = Pbindf(Pseq(f.chips, inf),
    \dur, 0.3,
    \zoom, 0.6,
    \instrument, i,
).play
)
p.stop

helpfile source: HelpSource/Classes/Fracture.schelp
link::Fracture/Classes/Fracture::

FractureExtension

Description

Class Methods

.new

Arguments:

.load

Arguments:

Instance Methods

.open

.close

.save

Arguments:

.clear

.lock

.chips

Returns:

.notes

Returns:

.noteChips

Returns:

.playNote

.buffer

Returns:

.filePath

Returns:

.defaultSynth

.writeInterval

.clearInterval

.ampThresh

.pitchThresh

.minDur

.minDur

Examples

Fracture
Extension