DIdev | SuperCollider 3.13.0 Help

Description

DIdev / PIdef / PLIdev search for numbers with integer distance from a source signal / pattern up to a given deviation. Repetitions within a lookback span are avoided, DIdev / PIdef / PLIdev randomly choose from possible solutions. Intended for search within integer grids (pitches, indices etc.), however applications with non-integer sources are possible, see examples.

NOTE: DIdev needs at least a SC version >= 3.7.0 for proper working.

NOTE: It's the user's responsibility to pass a combination of deviation and lookback values that allows a possible choice, see examples.

NOTE: In contrast to PIdev and PLIdev, DIdev needs to know maximum deviations (minLoDev, maxHiDev) beforehand. Together with maxLookBack they determine multichannel sizes, so a relatively high number of ugens might be involved.

Class Methods

.new

Creates a new DIdev object.

Arguments:

in	The source signal, integer distances are calculated from the value of this signal with each trigger. Can be demand rate or other ugen.
maxLookBack	Integer, the maximum lookback span. Fixed, defaults to 3.
minLoDev	Integer, the minimum low deviation (must not be exceeded by any loDev value). Should be negative, cannot be modulated, defaults to -3.
maxHiDev	Integer, the maximum high deviation (must not be exceeded by any hiDev value). Should be positive, cannot be modulated, defaults to 3.
lookBack	Determines the current lookback span for avoiding repetitions. Can be modulated (demand rate or other ugen, no ar) but must not exceed maxLookBack. If no value is passed, then maxLookBack is taken.
loDev	Determines the current low deviation for the search. Can be modulated (demand rate or other ugen) but must not exceed minLoDev. If not specified, them minLoDev is taken.
hiDev	Determines the current high deviation for the search. Can be modulated (demand rate or other ugen) but must not exceed maxHiDev. If not specified, then maxHiDev is taken.
thr	Threshold for equality comparison. Can be modulated (demand rate or other ugen). Defaults to 1e-3.
length	Number of repeats. Defaults to inf.

Examples

Ex. 1: Basic usage: random choice within region without repetitions

Ex. 2: Variable deviations and lookBack

Ex. 3: Moving source signal

Ex. 4: Dynamic deviation range and lookBack

// lookBack and deviations coupled here
// maxLookBack, minLoDev and maxHiDev must be large enough

(
x = {
    var trig = Impulse.ar(7);
    var dev = SinOsc.ar(0.1, -pi/2).range(1, 5);
    var midi = Demand.ar(trig, 0, 
        DIdev(78, 10, -5, 5, 
            SinOsc.kr(0.1, -pi/2).range(1, 5).round.poll(label: \lookBack),
            dev.neg.poll(label: \loDev),
            dev.poll(label: \hiDev)
        )
    );
    SinOsc.ar(midi.lag(0.007).midicps, 0, 0.1) ! 2
}.play;
)

x.release

// loDev and hiDev can be demand rate

(
x = {
    var trig = Impulse.ar(5);
    var hiDev = Dseq([1, 10], inf);
    var midi = Demand.ar(trig, 0,
        DIdev(78, 10, -10, 10,
            1,
            Dseq([-10, 5], inf),
            Dseq([-5, 10], inf)
        )
    );
    SinOsc.ar(midi.lag(0.007).midicps, 0, 0.1) ! 2
}.play;
)

x.release

// lookBack can also be demand rate

(
x = {
    var trig = Impulse.ar(5);
    var hiDev = Dseq([1, 10], inf);
    var midi = Demand.ar(trig, 0,
        DIdev(70, 10, -15, 15,
            Dstutter(4, Dseq([1, 3], inf)),
            Dstutter(4, Dseq([-9, 7], inf)),
            Dstutter(4, Dseq([-8, 10], inf))
        )
    );
    midi.poll(trig);
    SinOsc.ar(midi.lag(0.007).midicps, 0, 0.1) ! 2 * EnvGen.ar(Env.asr(0.15))
}.play;
)

x.release

Ex. 5: Non-integer source

Ex. 6: Multichannel expansion

Ex. 7: Application to other params: rhythm

// if we have indexed data for whatever, we can slide over it
// prepare some rhythms in order
// use them for SynthDef

(
~rhythmBase = [
    [1, 1],
    [2, 1, 1],
    [1, 1, 2],
].collect(_.normalizeSum);

~rhythms = ~rhythmBase *.x [1, 2];
~rhythmNum = ~rhythms.size;
~rhythms = ~rhythms.scramble;

"rhythm types: ".postln;
~rhythms.do { |r, i| i.post; ": ".post; r.postln };

SynthDef(\sine_rhythm, { |out = 0, freq = 400, att = 0.01, rel = 0.1, gate = 1, amp = 0.2|
    var trig, loDev = -1, hiDev = 1, sig, src,
        rhy = ~rhythmNum.collect { |i| Dseq(~rhythms[i], 1) };

trig = TDuty.ar(
        Dswitch(rhy,
            // be careful not to exceed range of rhythm indices, which can result in server quit
            Dpoll(
                DIdev(SinOsc.ar(0.1).range(loDev.abs, ~rhythmNum - hiDev - 1).round, 2, loDev, hiDev),
                'rhythm type'
            )
        ) * 0.3
    );
    src = SinOsc.ar(Demand.ar(trig, 0, LFDNoise3.ar([0.5, 3], [10, 15], [60, 85])).midicps);
    sig = Decay2.ar(trig, att, rel) * src;
    Out.ar(out, sig * EnvGen.ar(Env.asr(att, 1, rel), gate, doneAction: 2) * amp);
}).add;
)

x = Synth(\sine_rhythm)

x.release

Ex. 8: Proof of concept

Ex. 9: Switching signals with DXMix

// source of 10 stereo granulations:
// they differ in position movement, trigrate and rate

b = Buffer.read(s, Platform.miSCellaneousDirs[0] +/+ "Sounds" +/+ "kitchen_sounds_1.wav");

(
x = {
    var pos = { |i| SinOsc.ar(0.02, pi/5 * i).range(0.1, 0.8) } ! 10;
    var sig;

sig = pos.collect { |p, i|
        TGrains.ar(
            2,
            trigger: Impulse.ar(i * 10 + 30),
            bufnum: b,
            rate: LFDNoise3.ar(0.1).range(0.3, 1.5),
            centerPos: p * BufDur.ir(b),
            dur: 0.1,
            pan: Dseq([-1, 1], inf)
        )
    };
    // switch between stereo sources with DXMix
    DXMix.ar(
        Dpoll(DIdev(SinOsc.ar(0.1).range(2, 7).round, 2, -2, 1)),
        `sig,
        fadeMode: 1,
        stepTime: 0.03,
        fadeTime: 0.002
    ) * 5
}.play
)

x.release

// sine stereo sources

(
x = {
    var sig = (1..20).scramble.collect { |i| 
        SinOsc.ar(
            [i, 20-i] * 100 * LFDNoise3.ar(0.1).range(0.97, 1.03), 
            0, 
            0.05 * LFDNoise3.ar(1 ! 2).range(0.1, 1)
        )
    };
    DXMix.ar(
        Dpoll(DIdev(SinOsc.ar(0.05).range(2, 17).round, 2, -2, 2)),
        `sig,
        fadeMode: 1,
        stepTime: 0.03,
        fadeTime: 0.002
    ) ;
}.play
)

x.release

helpfile source: HelpSource/Classes/DIdev.schelp
link::miSCellaneous_lib/Classes/DIdev::

DIdevExtension

.new

Arguments:

DIdev
Extension