Wavesets | SuperCollider 3.13.0 Help

Description

Wavesets analyses soundfiles into short fragments called wavesets, and contains these waveset data and their info. It can support a variety of waveset based synthesis instruments.

By Trevor Wishart's definition, a waveset is a segment of an audio signal between one non-positive to positive zero crossing and the next. [ see T. Wishart (1994): Audible Design. ] Note that this definition only applies to mono signals.

In extension of that concept, the Wavesets class provides fractional zero crossings, amplitude analyses, and other statistical data.

See also the end of Chapter 16, Microsound, in the SuperCollider Book at MIT Press for detailed examples - code available here:

http://supercolliderbook.net/Server.default.boot; // make sure server is booted // make a wavesets from a soundfile w = Wavesets.from(String.scDir +/+ "sounds/a11wlk01.wav"); w.dump; // contains mainly analysis data w.plot(200, 1); // plot a single waveset w.signal.copyRange(w.xings[600], w.xings[601]).plot; w.plot(600, 1); // a single w.plot(600, 5); // a group of five contiguous wavesets w.buffer; w.buffer.play; // build and add the SynthDefs Wavesets.prepareSynthDefs; // eventFor returns an event that can be played directly w.eventFor(startWs: 600, length: 5, repeats: 2).postln.play; w.eventFor(startWs: 600, length: 2, playRate: 1, repeats: 5).postln.play; w.eventFor(startWs: 600, length: 2, playRate: 0.5, repeats: 5).postln.play; w.eventFor(700, 20, 5, 1).play; ( fork { 666.do { |i| var ev = w.eventFor(i * 5, 2, 5, exprand(0.5, 1.0)); ev.put(\pan, 1.0.rand2).play; ev.sustain.wait; } }; )

Class Methods

.prepareSynthDefs

prepare some basic synthdefs that can be used for Wavesets synthesis (when using the eventFor method).

.all

global dict for all instances of Wavesets

.at

access instances in Wavesets.all by name (key).

Arguments:

key

a symbol.

.clear

clear all existing wavesets from the Wavesets.all.

.from

make a Wavesets from a MONO soundfile at path.

Arguments:

path	the path to the soundfile.
name	the name by which to store the Wavesets instance.
toBuffer	flag whether to make a buffer that that soundfile. default = true.
server	the server on which to load the soundfile. default = s.

.new

make a new Wavesets instance. *from is much more common.

.minLength

The minimum number of sample points a single Waveset can have. This is used to avoid lots of extremely short samples in noisy samples. Logical minimum is 2, default is 10.

.defaultInst

get and set the name of the default synthdef to use in Wavesets event-related methods.

Instance Methods

Instance variables

.signal

the audio signal that was analysed.

.name

the wavesets name in the global dictionary

.buffer

a buffer on the server that was created from the same soundfile

.numFrames

the number of frames of the soundfile, the buffer and the Wavesets

.sampleRate

the sample rate of the signal/buffer. default is s.sampleRate

These variables are analysis result lists

.xings

all integer indices of the zero crossings found

.numXings

total number of zero crossings found

.lengths

lengths of all wavesets

.amps

peak amplitude of every waveset

.maxima

indices of positive maximum value in every waveset

.minima

indices of negative minimum value in every waveset

.fracXings

the calculated fractional zerocrossing points. This allows for more precise pitch information and waveset transitions, resulting in smoother sound.

.fracLengths

fractional lengths - in effect, this is 1/wavesetFreq.

These are overall statistics of the entire Wavesets

.minSet

shorted waveset

.maxSet

longest waveset

.avgLength

average length of all wavesets

.sqrAvgLength

weighted average length - so bigger wavesets have a larger impact

.minAmp

softest waveset amplitude

.maxAmp

loudest waveset amplitude

.avgAmp

average amplitude of the entire waveset

.sqrAvgAmp

weighted average of (squared) amplitude of the entire waveset

Further instance methods

.eventFor

generate an event for a given combination of start waveset index, number of wavesets, repeats, playback rate, and use of fractional crossings.

Arguments:

startWs, numWs, repeats, playRate, useFrac

.minima

.frameFor

.analyse

analyse the entire soundfile, then do finishFunc

.analyseFromTo

analyse the soundfile from given startFrame to endFrame

.calcAverages

analysis to do after loading.

.toBuffer

create a buffer for the Waevesets on the server given.

.plot

plot a section of <length> Wavesets from <startWs>

Examples

// The simplest usage is to ask the waveset to prepare an event for you.

w = Wavesets.from(String.scDir +/+ "sounds/a11wlk01.wav");

(
    fork {
        666.do { |i|
            var ev = w.eventFor((i * 5).postln, 2, 5, exprand(0.5, 1.0));
            ev.put(\pan, 1.0.rand2).play;
            ev.sustain.wait;
        }
    }
)

// play a single waveset or waveset group by hand
(
{     var startFr, endFr, dur;
    startFr = w.xings[800];
    endFr = w.xings[820];

dur = endFr - startFr / w.buffer.sampleRate;
    dur.postln;
    BufRd.ar(1, w.buffer, Line.ar(startFr, endFr, dur, doneAction: 2))
}.play;
)

// loop buffer segments with a Phasor:
(
x = { arg start = 0, end = 128, playRate = 1;
    BufRd.ar(1, w.buffer,
        Phasor.ar(0, playRate * BufRateScale.kr(w.buffer), start, end)
    )
}.scope(zoom: 8);
)

x.set(\start, 0, \end, 1024);    // just some random length, may buzz
x.set(\start, w.xings.at(100), \end, w.xings.at(101));
x.set(\start, w.xings.at(101), \end, w.xings.at(102));
x.set(\start, w.xings.at(100), \end, w.xings.at(200));
x.set(\start, w.xings.at(780), \end, w.xings.at(800));
x.set(\playRate, 0.25);
x.set(\playRate, 1);

x.release;

Task Examples

To play a waveset (or group) for a precise number of repetitions, one can use a SynthDef with a hard cutoff envelope, as below. Note that adding an offset outside the phasor works better; Phasor.ar(0, playRate, start, end) is sometimes off by a few samples. This is likely a 32bit float precision problem.( // the simplest synthdef as implented in *prepareSynthDefs: SynthDef(\wvst0, { arg out = 0, buf = 0, start = 0, length = 441, playRate = 1, sustain = 1, amp=0.2, pan; var phasor = Phasor.ar(0, BufRateScale.ir(buf) * playRate, 0, length) + start; var env = EnvGen.ar(Env([amp, amp, 0], [sustain, 0]), doneAction: 2); var snd = BufRd.ar(1, buf, phasor) * env; OffsetOut.ar(out, Pan2.ar(snd, pan)); }, \ir.dup(8)).add; ) Synth("wvst0", [\bufnum, b, \start, 0, \length, 5000, \sustain, 0.1]); // do the math by hand to understand it: ( var startWs = 100, length = 6, rep = 10, playRate = 0.5; var startframe, endframe, sustain; startframe = w.xings[startWs]; endframe = w.xings[startWs + length]; sustain = (endframe - startframe) * rep / playRate / w.sampleRate; Synth("wvst0", [ \bufnum, w.buffer, \start, startframe, \length, endframe - startframe, \playRate, playRate, \sustain, sustain, \amp, 1 ]); ) // the same done with eventFor: w.eventFor(100, 6, repeats: 10, playRate: 0.5).put(\amp, 1).play; ( Task({ 300.do({ arg i; var ev = w.eventFor(100 + i, 2, 10, 1); ev.putPairs([\pan, [-1, 1].choose, \amp, 0.5]); ev.play; (ev.sustain).wait; }); }).play; ) // compare fractional and integer xings: // especially for high frequency signals, // fractional does slightly cleaner looping and finer pitch gradations. // - better test below with ordering wavesets by length - ( Task({ [true, false].do { |usefrac| (1250..1500).do { arg i; var ev = w.eventFor(i, 1, 100, 1, useFrac: usefrac); ev.putPairs([/*\pan, 0 [-1, 1].choose,*/ \amp, 0.5]); ev.play; (ev.sustain).wait; }; 1.wait; }; }).play; ) // some variants waveset timestretch ( Task({ // segments of 10 wavesets, step by 1 => 10x longer (300, 301 .. 900).do { arg start; var ev = w.eventFor(start, numWs: 10, repeats: 1); ev.putPairs([\amp, 0.5]); ev.play; (ev.sustain).wait; }; 1.wait; // 1 waveset at a time, loop 10 times - much more 'pitch beads'-like (300, 301 .. 900).do { arg start; var ev = w.eventFor(start, numWs: 1, repeats: 10); ev.putPairs([\amp, 0.5]); ev.play; (ev.sustain).wait; }; }).play; ) // play them sorted by (integer) waveset length: w.lengths.plot; // lengths are very irregular o = w.lengths.order; ( Task { var start, end, startFr, endFr, dur, repeats; var order = w.lengths.order; [false, true].do { |useFrac| if (useFrac) { "fractional crossings - better pitch resolution." } { "integer crossings - pitches quantized to integer sample lengths." }.postln; order.do { arg start; var ev = w.eventFor(start, numWs: 1, repeats: 5); ev.putPairs([\amp, 0.5]); ev.play; (ev.sustain).wait; }; 0.5.wait; }; }.play; )

helpfile source: HelpSource/Wavesets.schelp
link::Wavesets/Wavesets::

WavesetsExtension

.prepareSynthDefs

.all

.at

Arguments:

.clear

.from

Arguments:

.new

.minLength

.defaultInst

.signal

.name

.buffer

.numFrames

.sampleRate

.xings

.numXings

.lengths

.amps

.maxima

.minima

.fracXings

.fracLengths

.minSet

.maxSet

.avgLength

.sqrAvgLength

.minAmp

.maxAmp

.avgAmp

.sqrAvgAmp

.eventFor

Arguments:

.minima

.frameFor

.analyse

.analyseFromTo

.calcAverages

.toBuffer

.plot

Wavesets
Extension