Simplex | SuperCollider 3.13.0 Help

Description

This class is just a group of functions to generate Simplex Noise (https://en.wikipedia.org/wiki/Simplex_noise) in 2D, 3D and 4D space. In a musical context, one-dimensional noise may be of more interest, but higher dimensions are useful, for example to allow the sequence to vary over time, or to produce looping pseudo-noise (the *periodic helper provides this functionaity).

The *noise2, *noise3 and *noise4 functions are based on the example Java code (in the public domain) by Stefan Gustavson, with optimizations by Peter Eastman. You can read the paper (http://staffwww.itn.liu.se/~stegu/simplexnoise/simplexnoise.pdf) or see the original code (http://weber.itn.liu.se/~stegu/simplexnoise/SimplexNoise.java).

The functions return noise values in the range of -1 to 1 (approximately; it may sometimes go slightly outside this range). Simplex noise is repeatable, so for the same inputs it will produce the same outputs. If you want to "reseed" it, use a transform (offset, scaling or rotation) on the 2D or 3D (vector) arguments.

For 1D noise, just use *noise2 with a constant value for yin.

First code examples:Simplex.noise2(215.33,-192.07); // -> 0.12348... Simplex.noise3(5.077, 7.508, 7.33); // -> -0.54564... Simplex.fBm4(11.2, 22.3, -34.5, 77.1, 4); // -> -0.04380...

Class Methods

.new

An error will be thrown if you try to make an instance of this class. It has no instance data and all methods are class methods.

.periodic

Periodic one-dimensional Simplex noise.// The `periodic` function loops from 0-1, 1-2, 2-3... (0,0.01..3).collect{ arg x; Simplex.periodic(x) }.plot;

Arguments:

x	The "time" (arbitary 1D parameter), typically from 0.0 to 1.0, at which to evaluate periodic noise. x outside the range of 0-1 will repeat.
offset	A scalar or vector of two values, used to offset the "origin" of the noise space. This can be used to provide a different noise "seed". Very small changes to the offset will provide small variations in the noise.
freqScale	Scaling of the noise space (effectively its "frequency"). Larger values will make the noise change direction more times in each cycle.
oct	How many octaves of noise to sum. This provides more random "detail". Useful range is generally from 1 to 8. Adding more octaves will increase calculation time.

.fBm2

Fractional (or fractal) Brownian motion (https://en.wikipedia.org/wiki/Fractional_Brownian_motion) noise in 2D, which performs of sum of increasingly higher-frequency octaves of 2D Simplex noise.

Arguments:

xin
yin	The 2D coordinates at which to evaluate the noise function.
oct	How many octaves of noise to sum. This provides more random "detail". Useful range is generally from 1 to 8. Adding more octaves will increase calculation time.

.fBm3

Fractional (or fractal) Brownian motion noise in 3D, which performs of sum of increasingly higher-frequency octaves of 3D Simplex noise.

Arguments:

xin
yin
zin	The 3D coordinates at which to evaluate the noise function.
oct	How many octaves of noise to sum. This provides more random "detail". Useful range is generally from 1 to 8. Adding more octaves will increase calculation time.

.fBm4

Fractional (or fractal) Brownian motion noise in 4D, which performs of sum of increasingly higher-frequency octaves of 4D Simplex noise.

Arguments:

xin
yin
zin
win	The 4D coordinates at which to evaluate the noise function.
oct	How many octaves of noise to sum. This provides more random "detail". Useful range is generally from 1 to 8. Adding more octaves will increase calculation time.

.noise2

A Simplex noise function in 2D. Takes a coordinate and returns a scalar "spatial noise" value.

Arguments:

xin
yin	The 2D coordinate at which to evaluate the noise function.

.noise3

A Simplex noise function in 3D. Takes a coordinate and returns a scalar "spatial noise" value.

Arguments:

xin
yin
zin	The 3D coordinate at which to evaluate the noise function.

.noise4

A Simplex noise function in 4D. Takes a coordinate and returns a scalar "spatial noise" value.

Arguments:

xin
yin
zin
win	The 4D coordinate at which to evaluate the noise function.

Instance Methods

None. Use the class methods, there is no need to create instances of Simplex class, since there is no instance-specific data.

Examples

(-1,-0.95..3).collect{ arg x; Simplex.noise2(x,-7.1) }.plot;

(
(-1,-0.98..3).collect{ arg x;
    (1..5).collect{ |oct| Simplex.fBm2(x, 2.35, oct) }
}.flop.plot;
)

// The `periodic` function loops from 0-1, 1-2, 2-3...
(0,0.01..3).collect{ arg x; Simplex.periodic(x) }.plot;

// You may change the "seed" by giving a different offset,
// and the "frequency" by changing the scale.
(0,0.01..3).collect{ arg x; Simplex.periodic(x, [173.2, -22.73], 0.5, 4) }.plot;

// It can be interesting to generate wavetable Buffers for sound
// synthesis using periodic noise. The following can sometimes
// sound quite string-like:
s.boot;
(
var scale = 0.25;
var octaves = 4;
var offset = rand2(100.0!2); // gaussian(10,1!2);
var frames = 512;
var buf;
~bufs = ~bufs ?? { 2.collect{ Buffer.alloc(s, frames*2, 1) } };
~curBuf = ~curBuf !? { ~curBuf + 1 % 2} ? 0;

buf = ~bufs[~curBuf];
buf.sendCollection(Signal.newClear(frames).waveFill{ arg x;
    Simplex.periodic(x, offset, scale, octaves)
}.normalize.asWavetable);

Ndef(\noiseOsc, {
    Pan2.ar(HPF.ar(Osc.ar(buf, Rand(24,60).midicps, 0, 0.1), 20), Rand(-0.3,0.3))
}).fadeTime_(1.5).play
)

// Draw an animated 2D slice of 3D noise
(
var width=64, height=64, a, persistance=0.75, octaves=4, scale=8;
var win = Window("A slice of 3D Simplex noise", Rect(128, 128, width*scale, height*scale), false);
var uv = UserView(win, Rect(0, 0, win.bounds.width, win.bounds.height));
uv.animate_(true).frameRate_(10).background_(Color.black);
uv.drawFunc = {
    height.do{ |y|
        width.do{ |x|
            var noise = Simplex.fBm3(x/width*2, y/height*2, AppClock.seconds*0.05, octaves);
            Pen.fillColor = Color.grey(noise.linlin(-1,1,0,1));
            Pen.fillRect(Rect.aboutPoint(Point(x, y)*scale, scale, scale));
        };
    };
};
win.front;
)

helpfile source: HelpSource/Classes/Simplex.schelp
link::SimplexNoise-SC/Classes/Simplex::

SimplexExtension

Description

Class Methods

.new

.periodic

Arguments:

.fBm2

Arguments:

.fBm3

Arguments:

.fBm4

Arguments:

.noise2

Arguments:

.noise3

Arguments:

.noise4

Arguments:

Instance Methods

Examples

Simplex
Extension