PopUpTreeMenu | SuperCollider 3.13.0 Help

Description

This class is modelled after PopUpMenu, but implements submenus.

Keyboard navigation (optional)

`space`	open
`arrows`	left, right, up, down
`[a-z,0-9]`	jump to item
`return`	select
`escape`	close

Known problems / todo

Menues that are close to the right-hand side of the screen and extend across the border will overlap.

Class Methods

.new

Create a new menu. To make it work one must set a -tree.

Instance Methods

.tree

Dictionary of dictionaries. Branches terminate if they have an empty dictionary as a value (= leaf).

Discussion:

The tree dictionary is unordered. By default branches and leaves on the same level will be sorted and displayed in alphabetic order. See -sortFunc.

Below is an example of a tree without branches - all leaves (keys) are on the same leve. This will be similar to a regular PopUpMenu..tree= ( 'symbol1': (), 'symbol2': () )

symbol1
symbol2

Next an example of a nested structure. This will create a submenu..tree= ( 'symbol1': ( 'symbol2': () ) )

symbol1
- symbol2

Symbols, numbers and strings can be used as keys (compared to the old version which only accepted symbols).( 1.1 : (11: () ), 2.2: (22: () ) )

1.1
- 11
2.2
- 22

NOTE: It is possible to create complex and deeply nested menu structures, but it is not a good idea. For ease of use rarely should one nest more than single level deep. Submenus of submenus are difficult to navigate.

.allowsReselection

Determines whether the action is triggered when selecting already selected item. Defaults to false.

Arguments:

A Boolean.

.currentLeaf

Array of keys pointing to current selection (leaves only). Empty if nothing selected. See -currentPath for reporting both branches and leaves.

.currentPath

Array of keys pointing to current selection. Empty if nothing selected.

.sortFunc

Set a custom Function to sort the tree dictionary in other ways than the default alphabetic order. Note that the -tree keys are converted and passed in to this function as symbols.

.hiliteColor

Get or set the selection color.

.value

Get or set the value.

Arguments:

path	Should be an array of keys.

Returns:

Array of keys pointing to the last selected node/leaf. nil if nothing selected.

.valueAction

Set the value and evaluate the action.

Arguments:

path	Should be an array of keys.

Actions

.action

Function that gets evaluated when some leaf is selected. Arguments passed in: this, value

.openAction

Function that gets evaluated when the popup menu is clicked. Arguments passed in: this, mouseX, mouseY

Discussion:

This can be used to automatically populate -tree and keep it in sync with files in a folder. See examples below.

.closeAction

Function that gets evaluated when the popup menu closes. Arguments passed in: this, mouseX, mouseY

Apperance

.bounds

Get or set the position and dimension of the menu as a Rect.

.font

Get or set the Font.

.hiliteColor

Get or set the selection color.

.icon

Get or set the String used as branch indicator. By default this is "▶"

.flashRate

Set the speed of the flashes for the select item animation. The default is 0.1

.numFlashes

Set the number of flashes for the select item animation. The default is 1

.margin

Get or set the size of the side margins. The default is 4

Examples

//--basic usage
(
var w= Window("test", Rect(400, 400, 300, 100)).front;
PopUpTreeMenu(w, Rect(30, 30, 100, 20))
.tree_(
    (
        'a drum': (),
        'bass': (
            'funky': (),
            'tuba': (),
            'unhip': ()
        ),
        'cello': ()
    )
);
)

//--simple example with action function
(
var w= Window("popuptreemenu - simple", Rect(400, 400, 300, 100)).front;
a= PopUpTreeMenu(w, Rect(50, 30, 100, 20))
.tree_(
    (
        'a drum': (),
        'bass': (
            'funky': (),
            'unhip': (
                'umpahTuba': (),  //three levels deep here but just for demo
                'umpahUpright': ()
            ),
            'alloy': ()  //NOTE: leaves alphabetically sorted by default
        ),
        'melo': ()
    )
);
a.action_{|view, val| ("selected:"+val).postln};
)
a.value_(['bass', 'funky'])
a.value_(['melo'])
a.valueAction_(['bass', 'unhip', 'umpahTuba'])

//--polling state of the menu in use - example also show custom color/font settings
(
var w= Window("popuptreemenu - state", Rect(400, 400, 300, 100)).front;
a= PopUpTreeMenu.new(w, Rect(10, 20, 200, 34))
.tree_(('aaa': (), 'bbb': (), 'ccc': ('123': (), '456': (), '789': ('hier': ()))))
.font_(Font("Arial", 24))
.background_(Color.red(1))
.hiliteColor_(Color.red(0.75))
.stringColor_(Color.red(0.5));
Routine({while({w.isClosed.not}, {
    ("path:"++a.currentPath).post;
    (" leaf:"++a.currentLeaf).post;
    (" value:"++a.value).postln;
    0.4.wait;
})}).play(AppClock);
)
//--changing position and font while active
a.value_(['aaa'])
a.bounds_(Rect(30, 30, 100, 20));
a.font_(Font("Geneva", 10));
a.refresh
a.value;
a.sortFunc= {|a, b| a>b}
a.sortFunc= nil  //the default
//cmd period to stop

//--scanning a folder each time menu is pressed.
//--slightly inefficient but keeps menu/folder in sync
(
var root= "~/Music".standardizePath;  //EDIT THIS!
var w= Window("popuptreemenu - scan", Rect(400, 400, 300, 100)).front;
var buildTreeFunc;
a= PopUpTreeMenu.new(w, Rect(10, 20, 200, 20)).items_([root.basename]);
buildTreeFunc= {|path|
    var deepPathMatch, syms, tree;
    var dir= path.dirname;
    deepPathMatch= {|pn|
        var arr= [];
        pn.pathMatch.do{|x|
            if(x.last.isPathSeparator, {
                arr= arr++deepPathMatch.value(PathName(x++"*"));
            }, {
                arr= arr++PathName(x);
            })
        };
        arr
    };
    syms= deepPathMatch.value(PathName(path)).collect{|x|
        var pathNoRoot= x.fullPath.copyToEnd(root.withTrailingSlash.size);
        pathNoRoot.split($/)
    };
    tree= ();
    syms.do{|x|
        var parent= tree;
        x.do{|y, i|
            var node= parent[y];
            if(node.isNil, {
                parent.put(y, ());
                parent= parent[y];
            }, {
                parent= node;
            });
        };
    };
    tree;
};
a.openAction_{|view, x, y|
    ("rebuilding tree of"+root).postln;
    view.tree= buildTreeFunc.value(root);  //build and replace tree
};
a.closeAction_{|view, x, y| "closing".postln};
a.action_{|view, val| ("selected:"+root++val.join($/)).postln};
)

helpfile source: HelpSource/Classes/PopUpTreeMenu.schelp
link::PopUpTreeMenu/Classes/PopUpTreeMenu::

PopUpTreeMenuExtension

.new

.tree

Discussion:

.allowsReselection

Arguments:

.currentLeaf

.currentPath

.sortFunc

.hiliteColor

.value

Arguments:

Returns:

.valueAction

Arguments:

.action

.openAction

Discussion:

.closeAction

.bounds

.font

.hiliteColor

.icon

.flashRate

.numFlashes

.margin

PopUpTreeMenu
Extension